# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ivy Foster <iff@archlinux.org>
# Contributor: Jakob Gruber <jakob.gruber@gmail.com>

pkgname=crawl-git
pkgver=0.32a0+834+geaf45d8e21
pkgrel=2
pkgdesc="Dungeon Crawl Stone Soup: open-source, single-player, role-playing \
         roguelike game of exploration and treasure-hunting"
url="https://crawl.develz.org/"
license=(GPL-2.0-or-later)
arch=(x86_64)
depends=(
  freetype2
  gcc-libs
  glibc
  glu
  hicolor-icon-theme
  libglvnd
  lua51
  ncurses
  sdl2
  sdl2_image
  sdl2_mixer
  sqlite
  ttf-dejavu
  zlib
)
makedepends=(
  bison
  flex
  git
  imagemagick
  mesa
  perl
  pngcrush
  python-yaml
)
provides=(stone-soup stone-soup-git)
conflicts=(stone-soup stone-soup-git)
replaces=(stone-soup-git)
source=("git+https://github.com/crawl/crawl")
b2sums=('SKIP')

pkgver() {
  cd crawl
  git describe --long | sed -r 's/^([^-]+)(-([^-]+))?-([0-9]+)-(g.*)$/\1\3+\4+\5/'
}

prepare() {
  cp -a crawl crawl-tiles
}

_make() {
  make -C $1/crawl-ref/source \
    EXTERNAL_FLAGS="$CXXFLAGS" \
    EXTERNAL_LDFLAGS="$LDFLAGS" \
    INSTALL_UGRP=root:root \
    MCHMOD=755 \
    NO_TRY_GOLD=1 \
    NO_TRY_LLD=1 \
    SOUND=1 \
    STRIP=/usr/bin/true \
    bin_prefix=bin \
    prefix=/usr \
    "${@:2}"
}

build() {
  _make crawl       all
  _make crawl-tiles all TILES=y GAME=crawl-tiles
}

package() {
  _make crawl       DESTDIR="$pkgdir" install install-xdg-data
  _make crawl-tiles DESTDIR="$pkgdir" install install-xdg-data TILES=y GAME=crawl-tiles

  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 crawl/LICENSE
}

# vim:set sw=2 sts=-1 et: